@echo off
setlocal
pushd "%~dp0"
rem **********************************************
rem *
rem * Tableau Desktop に付属のコマンド ライン ユーティリティを使って
rem * パブリッシュされた抽出データ ソースを更新する
rem *
rem * データソースの元データが更新されたときのみ
rem *
rem * OAuth を使用しない抽出データソースに使用
rem * 単一接続データソースの更新にのみ使用
rem * 詳しくは https://help.tableau.com/current/pro/desktop/ja-jp/extracting_TDE.htm
rem *
rem **********************************************

rem ---------------------------------------------------
rem - publishに必要な情報を設定する 以下を適宜置き換えてください 
rem ---------------------------------------------------

::Tableau Desktopが 2020.1 の場合
set tableau_bin=C:\Program Files\Tableau\Tableau 2020.1\bin

::datasourceの元データファイル(.tdeではなく、.csvとか.xlsとかのファイル名)
set original_file=C:\Users\xxx\Documents\Tableau\Cmd\datatest.csv

set server=http://xxxx
set datasource="xxx"
set project="xxx"
set user=xxx
set password="xxx"

::siteが規定の場合は指定なしでOK.指定する場合はPublishコマンドのパラメータにも追加してください
::詳しくは https://help.tableau.com/current/pro/desktop/ja-jp/extracting_TDE.htm
::set site=

rem ---------------------------------------------------
rem - メイン
rem ---------------------------------------------------

::元データファイルがなければ終了
if not exist %original_file% (
    echo ファイルが見つかりません %original_file%
    goto PROC_END
)

::bakファイル名を獲得
for %%a in (%original_file%) do set before_file=%%~na.bak

::bakファイルがなければ(初回起動時) Pablish
if not exist %before_file% (
    call :PUBLISH
    goto PROC_END
)

:: 更新日時取得
for %%b in (%original_file%) do set timestamp_original=%%~tb
for %%c in (%before_file%) do set timestamp_before=%%~tc

::元データの更新日付がbakより新しければ Publish
if "%timestamp_original%" gtr "%timestamp_before%" call :PUBLISH

goto PROC_END
rem ---------------------------------------------------
rem - Publishコマンド
rem ---------------------------------------------------
:PUBLISH
cd %tableau_bin%
tableau refreshextract --original-file "%original_file%" --force-full-refresh -s %server% --datasource %datasource% --project %project% -u %user% -p %password%

::bakファイルにコピー
cd "%~dp0"
copy /Y %original_file% %before_file%
exit /b

:PROC_END
popd
::pause
::